SINGLE-PHASE VOLTAGE CONTROLLER (voltcont.cir)
*** OUTPUT VOLTAGE IS V(3), OUTPUT CURRENT IS I(R) ***
**************** INPUT PARAMETERS *********************
.PARAM VS = 120                    ; source rms voltage
.PARAM ALPHA = 90                  ; delay angle in degrees
.PARAM R = 20                      ; load resistance
.PARAM L = 50mH                    ; load inductance
.PARAM F = 60                      ; frequency

.PARAM TALPHA = {ALPHA/(360*F)}    ; converts angle to time delay
.PARAM PW = {0.5/F}                ; pulse width for switch control
***************** CIRCUIT DESCRIPTION *********************
VS 1 0 SIN(0 {VS*SQRT(2)} {F})
S1 1 2 11 0 SMOD
D1 2 3 DMOD                        ; forward SCR
S2 3 5 0 11 SMOD
D2 5 1 DMOD                        ; reverse SCR
R 3 4 {R}
L 4 0 {L}
**************** MODELS AND COMMANDS ********************
.MODEL DMOD D
.MODEL SMOD VSWITCH (RON=.01)
VCONTROL 11 0 PULSE(-10 10 {TALPHA} 0 0 {PW} {1/F}) ;control for both switches
.TRAN .1MS 33.33MS 16.67MS .1MS UIC     ; one period of output
.FOUR 60 I(R)                           ; Fourier Analysis to get THD
.PROBE
.END