UNIPOLAR INVERTER -- PWM -- HIGH & LOW SPEED SWITCHES (pwmup3.cir)
* UNIPOLAR SWITCHING--S1,S4 HIGH FREQ; S2,S3 LOW FREQ
********** OUTPUT IS V(2,3) ******************
************ PARAMETERS *****************
.PARAM Mf = 20
.PARAM VDC = 100
.PARAM Fo = 60
.PARAM Ma = .9
.PARAM FC = {Mf*Fo}
***********************************************
VSOURCE 1 0 DC {VDC}
S1 1 2 40 50 SWITCH   ;high speed
S2 3 0 40 0  SWITCH   ;low speed
S3 1 3  0 40 SWITCH   ;low speed
S4 2 0 50 40 SWITCH   ;high speed
*FEEDBACK DIODES:
D1 2 1 DMOD
D2 0 3 DMOD
D3 3 1 DMOD
D4 0 2 DMOD
*LOAD:                        [ ENTER LOAD BETWEEN NODES 2 AND 3 ]
R 2 4 1
L 4 3 2.65MH IC=0
******************** TRIANGLE CARRIER ****************
Vtri 30 0 PULSE (0 1 0 {1/(2*FC)} {1/(2*FC)} 1NS {1/FC})
*FOR SWITCHES 1 AND 4
Vsin 40 0 SIN(0 {Ma} 60)
ETRI 50 0 VALUE={V(30)*V(40)/(ABS(V(40))+1N)}
*MODELS:
.MODEL SWITCH VSWITCH(RON=0.001 VON=.001 VOFF=-.001)
.MODEL DMOD D
*CONTROL STATEMENTS:
.PROBE
.TRAN 0.5MS 33.33MS 16.66ms 0.01ms UIC
.OPTIONS NOPAGE ITL5=0
.END