UNIPOLAR INVERTER -- PWM (pwmup2.cir)
*************** OUTPUT IS V(2,3) ***********************
* USING VCONT AND -VCONT .... ALL HIGH-SPEED SWITCHES
*VOLTAGE-CONTROLLED SWITCHES USED
************ CIRCUIT PARAMETERS ************************
.PARAM Mf=10
.PARAM Ma=.9
.PARAM Fo=60
.PARAM RLOAD = 10
.PARAM L = 20mH
.PARAM Fc={Mf*Fo}

VSOURCE 1 0 DC 100
*****************SWITCHES ***************************
S1 1 2 40 30 SWITCH       ; ON WHEN   VCONT > VCARRIER
S2 3 0 30 20 SWITCH       ; ON WHEN  -VCONT < VCARRIER
S3 1 3 20 30 SWITCH       ; ON WHEN  -VCONT > VCARRIER
S4 2 0 30 40 SWITCH       ; ON WHEN   VCONT < VCARRIER
************ FEEDBACK DIODES ************************
D1 2 1 DMOD
D2 0 3 DMOD
D3 3 1 DMOD
D4 0 2 DMOD
***************** LOAD *********************************
R 2 4 {RLOAD}             ; load between nodes 2 and 3
L 4 3 {L}  IC=0
************* TRIANGLE CARRIER ***********************
VS 30 0 PULSE (1 -1 0 {1/(2*Fc)} {1/(2*Fc)} 1ns {1/Fc})
************ REFERENCE FOR SWITCHES 1 AND 4*********
VC 40 0 SIN(0 {Ma} {Fo} 0 0 {-90/Mf})
************ REFERENCE FOR SWITCHES 2 AND 3 ********
VC- 20 0 SIN(0 {Ma} {Fo} 0 0 {-90/Mf+180})
******************** MODELS ***************************
.MODEL SWITCH VSWITCH(RON=0.001 VON=.05 VOFF=-.05)
.MODEL DMOD D
******************* CONTROL STATEMENTS *************
.PROBE
.TRAN 0.5MS 33.33MS  UIC
.OPTIONS NOPAGE ITL5=0
.END