UNIPOLAR PWM (pwmup1.cir)
* DEPENDENT SOURCES USED TO PRODUCE PWM VOLTAGE
****************** OUTPUT VOLTAGE IS V(A,B) **************************
************** PARAMETERS ******************************************
.PARAM VDC=100                    ; dc source
.PARAM MA=0.9                     ; amplitude modulation ratio
.PARAM FSINE=60                   ; frequency of sinusoidal reference
.PARAM MF=10                      ; frequency modulation ratio
.PARAM FTRI={FSINE*MF}            ; frequency of triangular carrier
******************* PWM SOURCE *************************************
VTRI 3 0 PULSE(1 -1 0 {1/(FTRI*2)} {1/(FTRI*2)} 1NS {1/FTRI})
*FOR SWITCHES 1 AND 4
VSIN1  1 0 SIN(0 {Ma} {FSINE} 0 0 {-90/Mf})
EPWMA A 0 VALUE = { VDC/2*( (V(1) - V(3))/ (ABS (V(1)-V(3) ) + 1N)+1)}
* FOR SWITCHES 2 AND 3
VSIN2 2 0 SIN(0 {Ma} {FSINE} 0 0 {-90/Mf+180})
EPWMB B 0 VALUE = { VDC/2*((V(2) - V(3)) / (ABS (V(2)-V(3) ) + 1N)+1)}
******************** LOAD *********************************************
R A X 10                          ; output between nodes A and B
L X B 20MH 
************************************************************************
.TRAN .1MS 33.33MS 16.66MS .01MS  ; delay output to observe steady state current
.PROBE
.END