FULL-BRIDGE INVERTER -- PWM (pwmbp2.cir)
************ OUTPUT IS V(2,3) ****************
**********INPUT PARAMETERS ****************
.PARAM Vsource   = 100       ; DC input to inverter
.PARAM Fo = 60               ; fundamental frequency
.PARAM Mf = 21               ; carrier, multiple of Fo
.PARAM Ma = .8               ; amplitude ratio
.PARAM Fc = {Mf*Fo}          ; carrier frequency

VS 1 0 DC {Vsource}          ; dc source
******* VOLTAGE-CONTROLLED SWITCHES *****
S1 1 2 40 30 SWITCH
S2 3 0 40 30 SWITCH
S3 1 3 30 40 SWITCH
S4 2 0 30 40 SWITCH
************** FEEDBACK DIODES *************
D1 2 1 DMOD
D2 0 3 DMOD
D3 3 1 DMOD
D4 0 2 DMOD
******************** LOAD ******************
R 2 4 10                     ; load between nodes 2 and 3
L 4 3 20MH 
*************** TRIANGLE CARRIER **************
Vtri 30 0 PULSE (1 -1 0 {1/(2*Fc)} {1/(2*Fc)} 1ns {1/Fc})
******************** REFERENCE *****************
Vcont 40 0 SIN(0 {Ma} {Fo} 0 0 {-90/Mf})
************ MODELS AND COMMANDS  *************
.MODEL SWITCH VSWITCH(RON=0.001  VON=.005 VOFF=-.005)
.MODEL DMOD D                ; default diode
.PROBE
.TRAN 0.5MS 33.33MS 16.67MS 0.1MS
.FOUR 60 25 I(R)
.OPTIONS NOPAGE ITL5=0
.END