BIPOLAR PWM (pwmbp1.cir)
* DEPENDENT SOURCE USED TO PRODUCE PWM VOLTAGE
****************** OUTPUT VOLTAGE IS V(3) **************************
************** PARAMETERS ******************************************
.PARAM VDC=100                ; dc source
.PARAM MA=0.8                 ; amplitude modulation ratio
.PARAM FSINE=60               ; frequency of sinusoidal reference
.PARAM MF=21                  ; frequency modulation ratio
.PARAM FTRI={FSINE*MF}        ; frequency of triangular carrier
******************* PWM SOURCE *************************************
VTRI 2 0 PULSE(1 -1 0 {1/(FTRI*2)} {1/(FTRI*2)} 1NS {1/FTRI})
VSIN 1 0 SIN(0 {MA} {FSINE} 0 0 {-90/MF})       ; synchronized w/triangular
EPWM 3 0 VALUE = { VDC* (V(1) - V(2)) / (ABS (V(1)-V(2) ) + 1N) }
******************** LOAD *********************************************
R 3 4 10                      ;output between nodes 3 and 0
L 4 0 20MH 
************************************************************************
.TRAN .1MS 33.33MS 16.66MS .01MS  ; delay output to observe steady state current
.FOUR 60 25 I(R)                  ;  Fourier coefficients through n = 25
.PROBE
.END