3-PHASE PWM INVERTER -- PWM SOURCES        (pwm3ph1.cir)
************ OUTPUTS ARE V(A,B) V(B,C) V(C,A) ***********
**************** CIRCUIT PARAMETERS *******************
.PARAM VDC = 100                 ; dc source
.PARAM Mf=9                      ; frequency modulation ratio
.PARAM Ma=.7                     ; amplitude modulation ratio
.PARAM Fo=60                     ; reference frequency
.PARAM R = 10                    ; load resistance
.PARAM L = 20M                   ; load inductance
.PARAM Fc={Mf*Fo}                ; computed carrier frequency
******************* CIRCUIT DESCRIPTION *****************
VSOURCE 1 0 DC {VDC}
************************** LOAD **************************
RA A AX {R}        ; node N is the neutral of the Y-connected load
LA AX N {L}
RB B BX {R}
LB BX N {L}
RC C CX {R}
LC CX N {L}
**********USE PULSE FUNCTION FOR TRIANGLE CARRIER ****
VS 2 0 PULSE (1 -1 0 {1/(2*Fc)} {1/(2*Fc)} 1ns {1/Fc})
********* REFERENCE SINE WAVES FOR EACH PHASE **********
VA 40 0 SIN(0 {Ma} {Fo} 0 0 {-90/Mf})
VB 50 0 SIN(0 {Ma} {Fo} 0 0 {-90/Mf - 120})
VC 60 0 SIN(0 {Ma} {Fo} 0 0 {-90/Mf - 240})
********************** PWM SOURCES ************************
EA A 0 VALUE = {(VDC/2)*((V(40) - V(2))/(ABS(V(40)-V(2))+1N)+1)}
EB B 0 VALUE = {VDC/2*((V(50) - V(2))/(ABS(V(50)-V(2))+1N)+1)}
EC C 0 VALUE = {VDC/2*((V(60) - V(2))/(ABS(V(60)-V(2))+1N)+1)}
******************** COMMANDS ***************
.PROBE
.TRAN 0.5MS 33.33MS  16.667M .005MS UIC
.OPTIONS NOPAGE ITL5=0
.END