PUSH-PULL SWITCHING CONVERTER (pushpull.cir)
*** output is V(9,6)
*********************** PARAMETERS *******************************
.PARAM Vs = 30               ; source voltage
.PARAM D = 0.3               ; duty ratio of each switch
.PARAM R = 6                 ; load resistance
.PARAM LX = 0.5mH            ; filter inductor
.PARAM C = 50UF              ; filter capacitor
.PARAM F = 10K               ; switching frequency
.PARAM LM = 100mH            ; magnetizing inductance (primary)
.PARAM NPNS = 2              ; primary to secondary transformer turns ratio
************** FOR INITIAL CONDITIONS *****************************
.PARAM ICCAP = {2*Vs*D/NPNS -.7}  ;expected output -- for IC
.PARAM ILXAVG={ICCAP/R}
.PARAM DELTAILX = {ICCAP*(.5-D)/(LX*F)}  ICLX={ILXAVG-DELTAILX/2}
********** CIRCUIT DESCRIPTION ************************************
VS 1 0 DC {Vs}
LP1 1 2 {LM}                    ; transformer primary 1
LP2 3 1 {LM}                    ; transformer primary 2
LS1 6 5 {LM/(NPNS*NPNS)}        ; transformer secondary 1
LS2 4 6 {LM/(NPNS*NPNS)}        ; transformer secondary 2
K LP1 LP2 LS1 LS2 {1 - 1p}      ; coupling between windings
S1 2 0 10 0 SMOD                ; ideal switch
S2 3 0 20 0 SMOD
D2 5 7 DMOD
D1 4 7 DMOD
RLINK 6 0 1M                    ; ties primary and secondary for pspice
LX 7 9 {Lx}  IC={ICLX}
C 9 6 {C} IC={ICCAP}
R 9 6 {R}
************************* SWITCH CONTROL ***************************
VPULSE1 10 0 PULSE (-10 10  0  {.01/F} {.01/F} {D/F} {1/F})
VPULSE2 20 0 PULSE (-10 10 {1/(2*F)} {.01/F} {.01/F} {D/F} {1/F})
******************* MODELS AND COMMANDS ****************************
.MODEL SMOD VSWITCH (RON=.01)
.MODEL DMOD D
.TRAN 1US 1MS UIC
.OPTIONS NOPAGE ITL5=0
.PROBE
.END