FULL-BRIDGE INVERTER (invbjt.cir)
****BJT SWITCHES WITH IDEALIZED BASE DRIVE CIRCUITS****
******************* OUTPUT IS V(2,3) ******************
******************** PARAMETERS *********************
.PARAM VDC = 100               ; dc input
.PARAM F=60                    ; fundamental frequency
.PARAM R = 10                  ;load resistance
.PARAM L = 25MH                ;load inductance
.PARAM T={1/F}                 ; period
.PARAM EPS=0.1MS               ;blanking time for switches
********************** CIRCUIT ************************
VDC 1 0 DC {VDC}
*****BJT'S****
Q1 1 6 2  QMOD
Q2 3 8 0  QMOD
Q3 1 10 3 QMOD
Q4 2 12 0 QMOD
***FEEDBACK DIODES***
D1 2 1 DMOD
D2 0 3 DMOD
D3 3 1 DMOD
D4 0 2 DMOD
***** IDEALIZED BASE CONTROL*************
.PARAM VG = 10 RG = 50  TRF = 10US
VBASE1 7 2 PULSE(0 {VG} 0 {TRF} {TRF} {T/2-EPS} {T})
RG1 7 6 {RG}
VBASE2 9 0 PULSE(0 {VG} 0 {TRF} {TRF} {T/2-EPS} {T})
RG2 9 8 {RG}
VBASE3 11 3 PULSE(0 {VG} {T/2} {TRF} {TRF} {T/2-EPS} {T})
RG3 11 10 {RG}
VBASE4 13 0 PULSE(0 {VG} {T/2} {TRF} {TRF} {T/2-EPS} {T})
RG4 13 12 {RG}
*****************LOAD*******************************
R 2 4 {R}
L 4 3 {L} IC=-9.31       ;initial condition from previous example
****************MODELS*****************************
.MODEL DMOD D            ;default models
.MODEL QMOD NPN
.PROBE
.TRAN 0.5MS 50MS 16.67MS 0.1MS UIC
.OPTIONS NOPAGE
.END