FORWARD SWITCHING CONVERTER (forward.cir)
****** output voltage is V(6)
************************* PARAMETERS ****************************
.PARAM Vs=170
.PARAM D = 0.294
.PARAM R=50
.PARAM LX = 1MH
.PARAM C=1000UF
.PARAM F=25K                     ; switching frequency
.PARAM LM=2MH                    ; magnetizing inductance (primary)
.PARAM N1N2=0.5                  ; n1/n2 of transformer
.PARAM N1N3=1                    ; n1/n3 of transformer
***************** CALCULATED PARAMETERS **************************
.PARAM Vo = {Vs*D/N1N2}
.PARAM ILMAVG={Vo*Vo/(Vs*R*D)}
.PARAM DELTAILM = {Vs*D/(LM*F)}  ICLM={ILMAVG-DELTAILM/2}
.PARAM ILXAVG = {Vo/R}
.PARAM DELTAILX = {(Vs/N1N2-Vo)*D/(LX*F)}
.PARAM ICLX = {ILXAVG-DELTAILX/2}
.PARAM ICCAP={Vo}
*********************  CIRCUIT  DESCRIPTION **********************
VS 1 0 DC {Vs}               ; source voltage
L1 1 2 {LM} IC=0             ; transformer primary
L2 4 0 {LM/(N1N2*N1N2)}      ; transformer secondary
L3 3 1 {LM/(N1N3*N1N3)}      ; transformer tertiary
K L1 L2 L3 {1 - 1P}          ; coupling between primary and secondary
S 2 0 20 0 SMOD              ; ideal switch
D1 4 5 DMOD
D2 0 5 DMOD
D3 0 3 DMOD
LX 5 6 {LX}  IC={ILXAVG}
C 6 0 {C}    IC={ICCAP}
R 6 0 {R}
************************* SWITCH CONTROL **************************
VPULSE 20 0 PULSE (-1 1  0  .5US .5US {D/F} {1/F})
********************** MODELS AND COMMANDS ************************
.MODEL SMOD VSWITCH (RON=.01 VON=.1 VOFF=-.1)
.MODEL DMOD D
.TRAN 1US 800US UIC          ; enter transient end time
.OPTIONS NOPAGE ITL5=0
.PROBE
.END