FLYBACK SWITCHING CONVERTER (flyback.cir)
**** output voltage is V(4)
************************    PARAMETERS    **********************
.PARAM Vs=24                     ; source voltage
.PARAM D = 0.4                   ; duty ratio
.PARAM R=5                       ; load resistance
.PARAM C=80UF                    ; output filter capacitor
.PARAM F=30K                     ; switching frequency
.PARAM LM=1000UH                 ; magnetizing inductance (primary)
.PARAM N1N2=2                    ; n1/n2 of transformer
****************** CALCULATED INITIAL CONDITIONS ******************
*(assumes continuous current)
.PARAM VO = {VS*(D/(1-D))/N1N2 }
.PARAM IAVG={VO*VO/(VS*R*D)}
.PARAM DELTAILM = {VS*D/(LM*F)}  ICLM={IAVG-DELTAILM/2}
.PARAM DELTAVO = {VO*D/(R*C*F)}
.PARAM ICCAP={VO+DELTAVO/2}
*********************  CIRCUIT  DESCRIPTION ************************
VS 1 0 DC {VS}                    ; source voltage
LP 1 2 {LM} IC={ICLM}             ; transformer primary
LS 0 3 {LM/(N1N2*N1N2)}           ; transformer secondary
K LP LS {1 - 1p}                  ; coupling between primary and secondary     
S 2 0 20 0 SMOD                   ; ideal switch
D 3 4 DMOD
C 4 0 {C} IC={ICCAP}
R 4 0 {R}
*************************** SWITCH CONTROL **************************
VPULSE 20 0 PULSE (-1 1  0  {.01/F} {.01/F} {D/F} {1/F})
************************ MODELS AND COMMANDS ************************
.MODEL SMOD VSWITCH (RON=.001 VON=.1 VOFF=-.1)
.MODEL DMOD D(n=.001)            ; ideal diode
.TRAN .1US 1000US UIC            ; enter transient analysis time
.OPTIONS NOPAGE ITL5=0
.PROBE
.END