PUSH-PULL CURRENT-FED SWITCHING CONVERTER (currfed.cir)
*** output is V(7,6)
*********************** PARAMETERS ******************************
.PARAM Vs = 30               ; source voltage
.PARAM D = 0.7               ; duty ratio of each switch
.PARAM R = 6                 ; load resistor
.PARAM LX = 0.5H             ; filter inductor
.PARAM C = 500UF             ; filter capacitor
.PARAM F = 10K               ; switching frequency
.PARAM LM = 1000mH           ; magnetizing inductance (primary)
.PARAM NPNS = 2              ; primary to secondary turns ratio
************** FOR INITIAL CONDITIONS ****************************
.PARAM ICCAP = {Vs/(2*(1-D)*NPNS) }  ;expected output -- for IC
.PARAM ICLX = {ICCAP/(2*R*(1-D)*NPNS)}
********** CIRCUIT DESCRIPTION **********************************
VS 1s 0 DC {Vs}                ; source voltage
LX 1s 1 {LX}  IC={ICLX}        ; input inductor
L1 1 2 {LM}                    ; transformer primary 1
L2 3 1 {LM}                    ; transformer primary 2
L3 6 5 {LM/(NPNS*NPNS)}        ; transformer secondary 1
L4 4 6 {LM/(NPNS*NPNS)}        ; transformer secondary 2
K L1 L2 L3 L4 {1-1p}           ; coupling between windings
S1 2 0 10 0 SMOD               ; ideal switch
S2 3 0 20 0 SMOD
D2 5 7 DMOD
D1 4 7 DMOD
RLINK 6 0 1M                   ; ties primary and secondary for pspice
C 7 6 {C} IC={ICCAP}
R 7 6 {R}
************************* SWITCH CONTROL **********************
VPULSE1 10 0 PULSE (10 -10  {D/F}  {.01/F} {.01/F} {(1-D)/F} {1/F})
VPULSE2 20 0 PULSE (10 -10 {(D-.5)/F} {.01/F} {.01/F} {(1-D)/F} {1/F})
******************* MODELS AND COMMANDS ***********************
.MODEL SMOD VSWITCH (RON=.01 )
.MODEL DMOD D
.TRAN 1US 1MS UIC
.OPTIONS NOPAGE ITL5=0
.PROBE
.END