NON-IDEAL BUCK REGULATOR USING SWITCH (bucknon.cir)
******* OUTPUT VOLTAGE IS V(4) *************************
********* CIRCUIT PARAMETERS **************************
.PARAM INPUT=50
.PARAM DUTY=0.4
.PARAM RLOAD=4
.PARAM L=1mH RL=0.4
.PARAM C=100UF  RESR=0.5
.PARAM RON=0.5                    ; on resistance of switch
.PARAM FREQUENCY=5K               ; switching frequency

.TRAN 10US 5MS 4MS 2US UIC       ; transient analysis, delay output for 4 ms to display steady-state
***************CIRCUIT DESCRIPTION*****************
VS 1 0 DC {INPUT}
SW 1 3 2 0 SMOD                   ; switch
D1 0 3 DMOD
L 3 4X {L} IC=3.8  ;IC estimate from last example
RL 4X 4 {RL}       ;inductor resistance
C 4 4Y {C} IC=20   ;IC estimate from last example
RESR 4Y 0 {RESR}  ;capacitor resistance
R 4 0 {RLOAD}
***************************************************
*Control for switch:
VPULSE 2 0 PULSE (-1 1  0  1nS 1nS {DUTY/FREQUENCY} {1/FREQUENCY})

.MODEL SMOD VSWITCH (RON={RON} VON=.1 VOFF=-.1)
.MODEL DMOD D
.OPTIONS NOPAGE ITL5=0
.PROBE
.END