LOOP CONTROL FOR FORWARD OR BUCK CONVERTER(buckloop.cir)
*Node 4 = filter output (across load resistor)
*Node 7 = compensator output
*Node 8 = PWM output = overall loop gain -- Enter VDB(8) and VP(8) in Probe 
*****CIRCUIT PARAMETERS**********
.PARAM L = 50UH      rL = 1p    ;Inductance and inductor resistance
.PARAM C = 100UF     rC = .5    ;Capacitance and capacitor resistance
.PARAM RLOAD = 4
.PARAM Vp = 2.5                 ;(peak of ramp in modulator)
*****CIRCUIT DESCRIPTION**********
VS 1 0 AC 1 0
rL 1 3 {rL}
L 3 4 {L}
rC 4 5 {rC}
C 5 0 {C}
R 4 0 {RLOAD}
XCOMP 4 0 7 COMP
*****COMPENSATED ERROR AMPLIFIER SUBCIRCUIT*****
.SUBCKT COMP 1 5 3
*TYPE 2 COMPENSATING NETWORK 1=INPUT; 5=+ (NONINVERTING INPUT); 3=OUTPUT
R1 1 2 1K
R2 4 3 8.7K
C1 2 4 .012uF
C2 2 3 760pf
EX 5 3 2 5 2E5    ;GAIN OF OPAMP
.ENDS COMP
*****PWM SUBCIRCUIT*****
XMOD 7 8 MODULATOR
.SUBCKT MODULATOR 1 2
*pulse-width modulator -- converts amplified error to duty ratio
RX 1 0 1G
EMOD 2 0 TABLE {V(1)/Vp} (0,0) (1,1)
RY 2 0 1G
.ENDS MODULATOR
.PROBE
.AC DEC 20 100 100000
.END