CONTROL FOR BUCK CONVERTER(buckcont.cir)
******** output voltage is V(4) **************
*************** CIRCUIT AND CONTROL PARAMETERS *********
.PARAM Vs = 20
.PARAM Vref = 8
.PARAM L = 100UH      rL = 2
.PARAM C = 80UF       rC = .6
.PARAM RLOAD = 5
.PARAM Vp = 3   ;(peak of ramp in modulator)
.PARAM R1 = 1K   R2 = 33K   C1= 1.45nF  C2 = 161pF ;error amplifier parameters

***************** CIRCUIT DESCRIPTION *******************
VS 1 0 DC {Vs}
XSWITCH 1 0 2 8     SWITCH
rL 2 3 {rL}
L 3 4 {L}   IC={Vref/RLOAD}
rC 4 5 {rC}
C 5 0 {C}  IC={Vref}
R 4 0 {RLOAD}
XCOMP 4 6 7 COMP     ;compensated error amplifier
Vref 6 0 {Vref}
XMOD 7 8 MODULATOR   ;PWM  controller

*************** STEP CHANGE IN LOAD **********************
R2 4 4S {RLOAD}      ;SWITCH ADDITIONAL LOAD RESISTOR
SW 4S 0 SCONT 0 SMOD
.MODEL SMOD VSWITCH(RON=.001)
VPULSE SCONT 0 PULSE(-10 10 .5M 1N 1N .5MS 10MS)

*********** COMPENSATED ERROR AMPLIFIER SUBCIRCUIT *******
.SUBCKT COMP 1 5 3
*TYPE 2 COMPENSATING NETWORK 1=INPUT; 5=+ (NONINVERTING INPUT); 3=OUTPUT
R1 1 2 {R1}
R2 4 3 {R2}
C1 2 4 {C1}
C2 2 3 {C2}
RIN 2 5 1E6
EAMP 3 0 TABLE {V(5,2)} (-15U,-15) (15U,15) ;saturation at +/- 15 volts
.ENDS COMP

************** PWM CONTROLLER SUBCIRCUIT ************
.SUBCKT MODULATOR 1 2
*pulse-width modulator -- converts amplified error to duty ratio
RX 1 0 1G
EMOD 2 0 TABLE {V(1)/VP} (0,0) (1,1)
RY 2 0 1G
.ENDS MODULATOR

********** AVERAGED SWITCH MODEL SUBCIRCUIT *********
* VORPERIAN'S SWITCH MODEL
.SUBCKT SWITCH  A  P  C  D
GAP A X VALUE {V(D)*I(VC)}
ECP X P VALUE={V(D)*V(A,0)}
VC X C 0
RCONV D 0 1G
.ENDS SWITCH

.PROBE
.TRAN 10U 2M UIC
.END