BOOST REGULATOR USING IDEAL SWITCH
*Output is v(3)
*ENTER CIRCUIT CONSTANTS HERE:
.PARAM INPUT=20
.PARAM OUTPUT=50
.PARAM RLOAD=12.5
.PARAM L=65uH                  ;INDUCTANCE VALUE
.PARAM C=200UF
*ICC={OUTPUT}      ;CAPACITANCE VALUE AND INITIAL CONDITION
.PARAM FREQUENCY=40K             ; SWITCHING FREQUENCY
.TRAN 1US 40ms 0 1u UIC          ; ENTER TRANSIENT END TIME
*********************CALCULATED VALUES**********************
.PARAM DUTY={1-(INPUT/OUTPUT)}
.PARAM IMIN={(INPUT/(RLOAD*(1-DUTY)*(1-DUTY)))-(INPUT*DUTY/(2*L*FREQUENCY))}
.PARAM IMAX={OUTPUT*OUTPUT/(INPUT*RLOAD) + (INPUT*DUTY/(2*L*FREQUENCY))}
*.PARAM ICC={(OUTPUT-1)+OUTPUT*DUTY/(RLOAD*FREQUENCY*C)} ;ALLOW 1V FOR DIODE
.PARAM ICC={(OUTPUT)-OUTPUT*DUTY/(RLOAD*FREQUENCY*C)}   ;IDEAL DIODE
******************CIRCUIT*********************************
VS 1 0 DC {INPUT}
SW 2 0 20 0 SMOD               ;(ideal switch)
D1 2 3 DMOD
L 1 2 {L} IC={IMIN}
C 3 0 {C} IC={ICC}
R 3 0 {RLOAD}
VPULSE 20 0 PULSE (1 -1  0  .1US .1US {DUTY/FREQUENCY} {1/FREQUENCY})
.MODEL SMOD VSWITCH (RON=.0001 ROFF=1E+6 VON=-.1 VOFF=.1)
.MODEL DMOD D(N=1E-2)
.OPTIONS NOPAGE ITL5=0
.PROBE
.END