FULL-BRIDGE INVERTER -- AMPLITUDE AND HARMONIC CONTROL (ampinv.cir)
*VOLTAGE-CONTROLLED SWITCHES USED
************ OUTPUT IS V(2,3) *************************************
*************** PARAMETERS *************************************
.PARAM ALPHA=30                  ;ALPHA IN DEGREES
.PARAM FREQUENCY=60              ;OUTPUT FUNDAMENTAL FREQ IN HZ.
.PARAM VDC = 116
.PARAM PERIOD={1/FREQUENCY}
.PARAM TALPHA={(ALPHA/360)*PERIOD}

Vsource 1 0 DC {VDC}
********** SWITCHES ********************
S1 1 2 30 0 SWITCH
S2 3 0 40 0 SWITCH
S3 1 3 0 40 SWITCH
S4 2 0 0 30 SWITCH
********* FEEDBACK DIODES *************
D1 2 1 DMOD
D2 0 3 DMOD
D3 3 1 DMOD
D4 0 2 DMOD
*************** LOAD *********************
R 2 2X 10                       ; load is between nodes 2 and 3
L 2X 3 25MH
************* CONTROL FOR SWITCHES *************************
V14 31 0 PULSE (-2 2 {TALPHA} 1NS 1NS {PERIOD/2} {PERIOD})
R14 31 30 1K
C14 30 0 1NF       ; (RC helps with convergence)
V23 41 0 PULSE (2 -2 {PERIOD/2 - TALPHA} 1NS 1NS {PERIOD/2} {PERIOD})
R23 41 40 1K
C23 40 0 1NF
******************** MODELS **********************************
.MODEL SWITCH VSWITCH(RON=0.01  VON=0.005 VOFF=-.005)
.MODEL DMOD D(N=.01)        ; ideal diode
************** CONTROL STATEMENTS *************************
.PROBE
.TRAN 0.1MS 50MS 16.66M .01M  UIC
.FOUR 60 13 V(2,3) I(R)
.OPTIONS NOPAGE NOMOD
.END