THREE-PHASE VOLTAGE CONTROLLER -- R-L LOAD (3phvc.cir)
*SOURCE AND LOAD ARE Y-CONNECTED (UNGROUNDED)
********************** INPUT PARAMETERS ****************************
.PARAM Vs=480            ; rms line-to-line voltage
.PARAM ALPHA=75          ; delay angle in degrees
.PARAM R=10              ; load resistance (y-connected)
.PARAM L = 30mH          ; load inductance
.PARAM F=60              ; source frequency
********************** COMPUTED PARAMETERS **************************
.PARAM Vm={Vs*SQRT(2)/SQRT(3)}  ; convert to peak line-neutral volts
.PARAM DLAY={1/(6*F)}           ; switching interval is 1/6 period
.PARAM PW={.5/F} TALPHA={ALPHA/(F*360)}
.PARAM TRF=10US         ; rise and fall time for pulse switch control
*********************** THREE-PHASE SOURCE **************************
VAN 1 0 SIN(0 {VM} 60)               
VBN 2 0 SIN(0 {VM} 60 0 0 -120)
VCN 3 0 SIN(0 {VM} 60 0 0 -240)
***************************** SWITCHES ********************************
S1 1 8 18 0 SMOD                        ; A-phase
D1 8 4 DMOD
S4 4 9 19 0 SMOD
D4 9 1 DMOD

S3 2 10 20 0 SMOD                       ; B-phase
D3 10 5 DMOD
S6 5 11 21 0 SMOD
D6 11 2 DMOD

S5 3 12 22 0 SMOD                       ; C-phase
D5 12 6 DMOD
S2 6 13 23 0 SMOD
D2 13 3 DMOD
***************************** LOAD **********************************
RA 4 4A  {R}                            ; van = v(4,7)
LA 4A 7 {L}

RB 5 5A {R}                             ; vbn = v(5,7)
LB 5A 7 {L}

RC 6 6A {R}                             ; vcn = v(6,7)
LC 6A 7 {L}
************************* SWITCH CONTROL *****************************
V1 18 0 PULSE(-10 10 {TALPHA}        {TRF} {TRF} {PW} {1/F})  
V4 19 0 PULSE(-10 10 {TALPHA+3*DLAY} {TRF} {TRF} {PW} {1/F})   
V3 20 0 PULSE(-10 10 {TALPHA+2*DLAY} {TRF} {TRF} {PW} {1/F})
V6 21 0 PULSE(-10 10 {TALPHA+5*DLAY} {TRF} {TRF} {PW} {1/F})
V5 22 0 PULSE(-10 10 {TALPHA+4*DLAY} {TRF} {TRF} {PW} {1/F})
V2 23 0 PULSE(-10 10 {TALPHA+DLAY}   {TRF} {TRF} {PW} {1/F})
************************ MODELS AND COMMANDS *************************
.MODEL SMOD VSWITCH(RON=0.01)
.MODEL DMOD D
.TRAN .1MS 50MS 16.67ms .05MS UIC
.FOUR 60 I(RA)                   ; Fourier analysis of line current
.PROBE
.OPTIONS NOPAGE ITL5=0
.END