THREE-PHASE SIX-STEP INVERTER (3phinv.cir)
************ OUTPUTS ARE V(A,B) V(A,N), etc.  *******
************ INPUT PARAMETERS *********************
.PARAM Vdc   = 100           ; DC input to inverter
.PARAM R = 10
.PARAM L = 20mH
.PARAM Fo = 60               ; fundamental frequency
.PARAM PERIOD={1/Fo}
*******************************************************
VS 1 0 DC {Vdc}
*********** VOLTAGE-CONTROLLED SWITCHES ********
S1 1 A CON14 0 SWITCH
S2 C 0 CON25 0 SWITCH
S3 1 B CON36 0 SWITCH
S4 A 0 0 CON14 SWITCH
S5 1 C 0 CON25 SWITCH
S6 B 0 0 CON36 SWITCH
*******************FEEDBACK DIODES ******************
D1 A 1 DMOD
D2 0 C DMOD
D3 B 1 DMOD
D4 0 A DMOD
D5 C 1 DMOD
D6 0 B DMOD
************* LOAD Y-CONNECTED: A-N, B-N, C-N********
RA A AX {R}
LA AX N {L}
RB B BX {R}
LB BX N {L}
RC C CX {R}
LC CX N {L}

**********************SWITCH CONTROL ********************
VCON14 CON14 0 PULSE(-10 10 0 1US 1US {PERIOD/2} {PERIOD})
VCON25 CON25 0 PULSE(-10 10 {PERIOD/6} 1US 1US {PERIOD/2} {PERIOD})
VCON36 CON36 0 PULSE(-10 10 {PERIOD/3} 1US 1US {PERIOD/2} {PERIOD})
************ MODELS AND CONTROL STATEMENTS ***********
.MODEL SWITCH VSWITCH(RON=0.001)
.MODEL DMOD D
.PROBE
.TRAN 0.5MS 33.33MS 16.66MS  UIC
.FOUR 60 20 V([A],[B]) I(RA)
.OPTIONS NOPAGE ITL5=0
.END