CONTROLLED THREE-PHASE BRIDGE RECTIFIER...6 PULSE (3phcont.cir)
*FOR USE WITH THE EVALUATION VERSION 
*******  BRIDGE OUTPUT IS V(4,5) *****
******* CIRCUIT PARAMETERS *******************
.PARAM ALPHA=39.5
.PARAM VLLRMS = 480
.PARAM R=10
.PARAM L= 50M
.PARAM VM={SQRT(2)*VLLRMS/SQRT(3)} F=60 DEL={1/(6*F)} PW={1/(2.9*F)}
.PARAM PERIOD={1/F}
************** SOURCE *************************
VAN 1 0 SIN(0 {VM} {F} 0 0 30)
VBN 2 0 SIN(0 {VM} {F} 0 0 -90)
VCN 3 0 SIN(0 {VM} {F} 0 0 -210)
************* 3-PHASE BRIDGE ******************
S1 1 8 18 0 SMOD
D1 8 4 DMOD
S4 5 9 19 0 SMOD
D4 9 1 DMOD
S3 2 10 20 0 SMOD
D3 10 4 DMOD
S6 5 11 21 0 SMOD
D6 11 2 DMOD
S5 3 12 22 0 SMOD
D5 12 4 DMOD
S2 5 13 23 0 SMOD
D2 13 3 DMOD
************* LOAD ****************************
R 4 4a {R}
L 4A 5 {L}
************* SWITCH CONTROL ******************
V1 18 0 PULSE(-10 10 {ALPHA*PERIOD/360}       0 0 {PW} {PERIOD})
V4 19 0 PULSE(-10 10 {ALPHA*PERIOD/360+3*DEL} 0 0 {PW} {PERIOD})
V3 20 0 PULSE(-10 10 {ALPHA*PERIOD/360+2*DEL} 0 0 {PW} {PERIOD})
V6 21 0 PULSE(-10 10 {ALPHA*PERIOD/360+5*DEL} 0 0 {PW} {PERIOD})
V5 22 0 PULSE(-10 10 {ALPHA*PERIOD/360+4*DEL} 0 0 {PW} {PERIOD})
V2 23 0 PULSE(-10 10 {ALPHA*PERIOD/360+DEL}   0 0 {PW} {PERIOD})
************ COMMANDS AND MODELS ***************
.MODEL SMOD VSWITCH(RON=0.01)
.MODEL DMOD D
.TRAN .1MS 100MS 66.67MS .1MS UIC
.FOUR 60 I(VAN) I(R)
.PROBE
.OPTIONS NOPAGE NOMOD NOBIAS ITL5=0
.END